Datamodell og mål

Når tabellene er lastet inn, kobler du dem sammen og legger til noen mål. Alt her gjøres i Power BI Desktop, utenfor Power Query Editor.

Relasjoner

Åpne Model-visningen. Power BI kan finne noen av relasjonene selv. Sørg for at du har nøyaktig disse, alle én-til-mange med filtrering i én retning:

Fra (én)	Til (mange)
Portfolios[id]	Properties[portfolio_id]
Properties[id]	Hazards[property_id]
Properties[id]	Biodiversity[property_id]
Properties[id]	Buildings[property_id]
Properties[id]	EnergyCertificates[property_id]

EnergyCertificates[building_id] peker også til Buildings[id], men ikke legg til den relasjonen. Den ville gitt en ekstra vei fra Properties til EnergyCertificates, og det klarer ikke Power BI å løse.

Filtrer eiendommer på klimafarene deres

Med relasjoner i én retning filtrerer en slicer på Properties tabellen Hazards, men ikke omvendt. Vil du at en slicer som "Klimafare = landslide, Eksponering = HIGH" skal filtrere en tabell med eiendommer, kan du enten:

• sette Cross filter direction for relasjonen Properties → Hazards til Both, eller
• beholde én retning og bruke mål som dem nedenfor, som gjør filtreringen selv.

Sett bare én resultattabell til Both. Flere ville gjort modellen tvetydig.

Sorter nivåene

Tekstnivåer sorteres alfabetisk som standard, så HIGH ville kommet før LOW. Spørringen Hazards legger til kolonnen exposure_order for dette. I Table-visningen velger du Hazards[exposure], deretter Column tools → Sort by column → exposure_order.

Gjør det samme for sensitivity, vulnerability eller energimerker hvis du bruker dem i visualiseringer. Tillatte verdier viser hver skala fra lavest til høyest.

Mappehierarki

Portfolios[path] inneholder hele navnet, for eksempel Norway / Oslo / Office, som fungerer godt i slicere og tabeller. For et hierarki du kan drille ned i, legger du til beregnede kolonner:

Portfolio path ids = PATH ( Portfolios[id], Portfolios[parent_id] )

Level 1 =
LOOKUPVALUE (
    Portfolios[name],
    Portfolios[id], PATHITEM ( Portfolios[Portfolio path ids], 1 )
)

Level 2 =
LOOKUPVALUE (
    Portfolios[name],
    Portfolios[id], PATHITEM ( Portfolios[Portfolio path ids], 2 )
)

Legg til like mange nivåer som den dypeste mappen din har, og bygg så et hierarki av dem.

Mål

Legg til disse med Home → New measure. De teller bare relevante klimafarer, som er det de fleste klimarisikorapporter bør vise. Se relevans.

Property count = DISTINCTCOUNT ( Properties[id] )

Portfolio value = SUM ( Properties[value_estimate] )

Properties with high exposure =
CALCULATE (
    DISTINCTCOUNT ( Hazards[property_id] ),
    Hazards[relevant] = TRUE (),
    Hazards[exposure] IN { "HIGH", "VERY_HIGH" }
)

Value with high exposure =
SUMX (
    FILTER (
        Properties,
        CALCULATE (
            COUNTROWS ( Hazards ),
            Hazards[relevant] = TRUE (),
            Hazards[exposure] IN { "HIGH", "VERY_HIGH" }
        ) > 0
    ),
    Properties[value_estimate]
)

Share of value with high exposure =
DIVIDE ( [Value with high exposure], [Portfolio value] )

Hazards without sensitivity =
CALCULATE (
    COUNTROWS ( Hazards ),
    Hazards[relevant] = TRUE (),
    ISBLANK ( Hazards[sensitivity] )
)

Properties near sensitive nature =
CALCULATE (
    DISTINCTCOUNT ( Biodiversity[property_id] ),
    Biodiversity[relevant] = TRUE (),
    NOT ISBLANK ( Biodiversity[proximity] )
)

Certificates expiring within a year =
CALCULATE (
    COUNTROWS ( EnergyCertificates ),
    EnergyCertificates[expires_at] >= TODAY (),
    EnergyCertificates[expires_at] < EDATE ( TODAY (), 12 )
)

value_estimate er i eiendommens lokale valuta, som er NOK for norske eiendommer. Power BI laster inn tidsstemplene som dato/klokkeslett i UTC.

Ideer til rapporter

• Risikomatrise: en matrisevisualisering med Hazards[name] på radene, Hazards[exposure] i kolonnene og Property count som verdier, filtrert på relevante klimafarer.
• Verdi i fare per klimafare: et stolpediagram med Value with high exposure per Hazards[name].
• Mappeoversikt: en tabell med Portfolios[path], Property count, Portfolio value og Share of value with high exposure.
• Kart: API-et returnerer ikke koordinater, men kartvisualiseringene kan plassere eiendommer ut fra address, postal_code, postal_area og country. Angi Data category for hver kolonne under Column tools.
• Vurderinger som gjenstår: Hazards without sensitivity per mappe viser hvor følsomhetsvurderinger fortsatt mangler.
• Energi: et stolpediagram med bygninger per EnergyCertificates[label], og en liste over energiattester som utløper innen et år.